【Excel VBA】ユーザーフォームでデータベースの取得と入力をする

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
  
  'Enterキー以外は、終了
  If KeyCode <> vbKeyReturn Then Exit Sub
  
  ListBox1.Clear 'リストボックスをクリア
  ListBox1.ColumnCount = 2 '2列にする
  For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
    '検索値を含む場合
    If InStr(Cells(i, "B"), TextBox1.Value) > 0 Then
      With ListBox1
        .AddItem "" '行を追加
        .List(.ListCount - 1, 0) = Cells(i, "A") 'Noを取得
        .List(.ListCount - 1, 1) = Cells(i, "B") '商品を取得
      End With
    End If
  Next
  
  '検索値が見つかった場合
  If ListBox1.ListCount > 0 Then
    ListBox1.SetFocus 'リストボックスをフォーカス
    ListBox1.ListIndex = 0 '0行目を選択
  '見つからなかった場合
  Else
    'テキストボックスをフォーカスしたままにする
    KeyCode = 0
  End If
  
End Sub

Private Sub ListBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
  
  If KeyCode <> vbKeyReturn Then Exit Sub 'Enterキー以外は終了
  If ListBox1.ListIndex = -1 Then Exit Sub '選択されていない場合は終了
  
  Dim A
  With ListBox1
    '選択行のNoを取得
    A = Val(.List(.ListIndex, 0))
  End With
  
  For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
    'Noが一致した場合
    If Cells(i, "A") = A Then
      TextBox2.Value = A 'Noを取得
      TextBox3.Value = Cells(i, "B") '商品を取得
      TextBox4.Value = Cells(i, "C") '価格を取得
      TextBox5.Value = Cells(i, "D") '数量を取得
    End If
  Next
  
End Sub

Private Sub CommandButton1_Click()
  
  For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
    '同じNoの場合
    If Cells(i, "A") = Val(TextBox2.Value) Then
      Cells(i, "B") = TextBox3.Value '商品を入力
      Cells(i, "C") = TextBox4.Value '価格を入力
      Cells(i, "D") = TextBox5.Value '数量を入力
    End If
  Next
  
End Sub

Private Sub CommandButton4_Click()
  
  'テキストボックスとリストボックスをクリア
  TextBox1.Value = ""
  TextBox2.Value = ""
  TextBox3.Value = ""
  TextBox4.Value = ""
  TextBox5.Value = ""
  ListBox1.Clear
  
End Sub

Private Sub CommandButton2_Click()
  
  '最終行
  With Cells(Rows.Count, "A").End(xlUp)
    .Offset(1, 0) = WorksheetFunction.Max(Range("A:A")) + 1 '新規でNoを入力
    .Offset(1, 1) = TextBox3.Value '商品を入力
    .Offset(1, 2) = TextBox4.Value '価格を入力
    .Offset(1, 3) = TextBox5.Value '数量を入力
  End With
  
  'テキストボックスとリストボックスはクリア
  TextBox1.Value = ""
  TextBox2.Value = ""
  TextBox3.Value = ""
  TextBox4.Value = ""
  TextBox5.Value = ""
  ListBox1.Clear
  
End Sub

Private Sub CommandButton3_Click()
    
  For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
    '同じNoの場合
    If Cells(i, "A") = Val(TextBox2.Value) Then
      Rows(i).Delete '行を削除
    End If
  Next
  
  'テキストボックスとリストボックスをクリア
  TextBox1.Value = ""
  TextBox2.Value = ""
  TextBox3.Value = ""
  TextBox4.Value = ""
  TextBox5.Value = ""
  ListBox1.Clear
  
End Sub

Sub TEST()
  
  UserForm1.Show
  
End Sub